Formula Excel: valoare minimă dacă este unică -

Formula generică

=MIN(UNIQUE(range,0,1))

rezumat

Pentru a găsi valoarea unică minimă într-un set de date, puteți utiliza funcția UNIQUE împreună cu funcția MIN. În exemplul de mai jos, formula din E5 este:

=MIN(UNIQUE(data,0,1))

unde „date” este intervalul numit B5: B14.

În versiunile mai vechi de Excel, puteți utiliza o formulă matrice bazată pe funcțiile MIN, IF și COUNTIF, după cum se explică mai jos.

Explicaţie

Scopul din acest exemplu este de a returna valoarea minimă care este unică, adică valoarea minimă care apare o singură dată în date.

Funcția UNIQUE, nouă în Excel 365, va returna o listă unică de valori dintr-un set de date. În mod implicit, aceasta este o listă cu orice valoare care apare de una sau mai multe ori în date.

UNIQUE are un al treilea argument opțional numit „exact_once” care va limita rezultatele la valorile care apar o singură dată în datele sursă. Pentru a activa această caracteristică, argumentul trebuie setat la TRUE sau 1.

Funcționând din interior spre exterior, funcția UNIQUE este configurată astfel:

UNIQUE(data,0,1)

Pentru matrice, oferim datele de interval denumite . Pentru argumentul by_col, folosim zero (0), deoarece vrem valori unice pe rânduri, nu pe coloane. În cele din urmă, pentru exact_once, oferim 1, deoarece vrem numai valori care apar doar o dată în datele sursă.

Configurat în acest fel, UNIQUE returnează cele 4 valori care apar o singură dată:

(700;600;500;300) // result from unique

Această matrice este returnată direct la funcția MIN, care returnează valoarea minimă, 300, ca rezultat final:

=MIN((700;600;500;300)) // returns 300

Formula matricei cu COUNTIF

Dacă utilizați o versiune de Excel fără funcția UNIQUE, puteți găsi valoarea minimă unică cu o formulă matrice bazată pe funcțiile COUNTIF, MIN și IF.

(=MIN(IF(COUNTIF(data,data)=1,data)))

Aceasta este o formulă matrice și trebuie introdusă cu control + shift + enter, cu excepția Excel 365.

Funcționând din interior spre exterior, funcția COUNTIF este utilizată pentru a genera un număr al fiecărei valori din date astfel:

COUNTIF(data,data) // count all values

Deoarece există 10 valori în datele de interval denumite , COUNTIF returnează o matrice de 10 rezultate:

(2;1;1;2;1;2;2;2;1;2)

Această matrice deține numărul fiecărei valori. Apoi testăm matricea pentru valori egale cu 1:

(2;1;1;2;1;2;2;2;1;2)=1

Din nou, obținem o matrice cu 10 rezultate:

(FALSE;TRUE;TRUE;FALSE;TRUE;FALSE;FALSE;FALSE;TRUE;FALSE)

Fiecare valoare TRUE corespunde unei valori din datele sursă care apare o singură dată. Această matrice este livrată direct la funcția IF, care o folosește ca un filtru. Numai valorile din datele asociate cu ADEVĂRAT intră în tabloul returnat de IF, toate celelalte valori sunt FALSE.

(FALSE;700;600;FALSE;500;FALSE;FALSE;FALSE;300;FALSE)

Această matrice este returnată direct funcției MIN care ignoră automat valorile logice și returnează minimul valorilor rămase, 300, ca rezultat final.

Articole interesante...